Pyrotech in 1.14.4 and beyond!

Hi, I'm Codetaylor, the creator of Pyrotech and I would love to work on moving the mod to more recent versions of Minecraft. If you'd like to see Pyrotech move beyond 1.12.2, click here to read more about my campaign to make that happen!

Class

import mods.pyrotech.BrickKiln;

Methods

static void addRecipe(
  string name,       // unique recipe name
  IItemStack output, // recipe output
  IIngredient input, // recipe input
  int burnTimeTicks  // recipe duration in ticks
);

static void addRecipe(
  string name,              // unique recipe name
  IItemStack output,        // recipe output
  IIngredient input,        // recipe input
  int burnTimeTicks,        // recipe duration in ticks
  float failureChance,      // chance for item to fail conversion
  IItemStack[] failureItems // array of randomly chosen failure items
);

static void removeRecipes(
  IIngredient output // output ingredient to match
);

static void removeAllRecipes();

static void setGameStages(
  Stages stages // game stages
);

Sets game stage logic required to use the device.

Examples

import mods.pyrotech.BrickKiln;

// fire a cobblestone block into a stone block in five minutes
BrickKiln.addRecipe("stone_from_cobblestone", <minecraft:stone>, <minecraft:cobblestone>, 6000);

// fire a cobblestone block into a stone block in five minutes with a 25% chance
// to fail and instead produce dirt
BrickKiln.addRecipe("stone_from_cobblestone", <minecraft:stone>, <minecraft:cobblestone>, 6000, 0.25, [<minecraft:dirt>]);